#xtranslate cabEntry  CREATE BROWSE  <oBrow> ;     // Variável que conterá o objeto
                     [AT            <nTop>,<nLeft>, <nBot>,<nRight>] ;  // Screen Coord.
                     [DATASOURCE     <xSource>] ;    // Fonte de dados
                     [DESCRIPTION    <aDescri>] ;    // Array contendo a descrição. Vide:
                                                      ;// cabEntry CREATE DESCRIPTION
                                                      ;// cabEntry ADD COLUMN
                     [BOX           <aBox>] ;                           // Tipo do Box
                     [BROWCOLOR     <cBrowColor>] ;// Cor do Browse
                     [FORMDESCRIPT  <aFormDesc>] ; // Vide CREATE FORMDESC
                     [HASHBARR      <lHBarr>] ;    // Exibir barra de rolagem horizontal?
                     [HASVBARR      <lVBarr>] ;    // Exibir barra de rolagem vertical?
                     [SHOWHEADER    <lShowHeader>] ;// Exibir o cabeçalho?
                     [HEADERSEP     <cHeadSep>] ;  // Separador do cabeçalho e colunas
                     [COLSEP        <cColSep>] ;   // Separador geral das colunas
                     [FOOTSEP       <cFootSep>] ;  // Separador geral dos rodapés
                     [FREEZE        <nFreeze>] ;   // Quantidade de colunas a congelar
                     [ROWIDENT      <bIdent>] ;    // Bloco de identificar a linha
                     [ROWBYROW      <lRowByRow>] ; // Movimentar linha a linha?
                     [ATSETFOCUS    <bAtSetFocus>] ;        // Bloco para executar quando
                                                               ;// a linha recebe o foco
                     [ATKILLFOCUS   <bAtKillFocus>] ;      // Bloco para executar quando a
                                                              ;// linha perde o foco
                     [ATCLOSE       <bClose>] ;    // Bloco para se executar quando se
                                                      ;// vai encerrar a edição
                     [EXITTOP       <lExitTop>] ;  // Retornar ao programa em :hitTop?
                     [EXITBOTTOM    <cExitBottom:YES,NO,ALERT,&>] ; // Pode-se sair
                                                      ;// em :hitBottom?
                     [EXITFORMBOTTOM <cExitFormBottom:YES,NO,ALERT,&>] ; // Pode-se sair
                                                      ;// em :hitBottom?
                     [FILTER        <bFilter>] ;   // Filtro para a Fonte de Dados
                     [SPECIALPROC   <bSpecProc>] ; // Procedimentos especiais quando se
                                                      ; // vai iniciar e encerrar o
                                                      ; // Event loop
                     [DELETESPEC    <aDelete>] ;   // Descrição dos procedimentos para
                                                     ; // deleção de linhas
                     [CANAPPEND     <lCanAppend>] ;// Pode-se acrescentar novas linhas?
                     [CANEDIT       <lCanEdit>] ;   // Browse pode ser editado?
            => <oBrow> := EditBrow_(<nTop>,<nLeft>,;
                                    <nBot>,<nRight>,;
                                    <xSource>,;
                                    <aDescri>,;
                                    <cBrowColor>,;
                                    <aFormDesc>,;
                                    <cHeadSep>,      <cColSep>,   <cFootSep>,;
                                    <nFreeze>,;
                                    <lShowHeader>,   <lHBarr>,    <lVBarr>,;
                                    <{bIdent}>,      <lRowByRow>,;
                                    <lExitTop>,      <lCanAppend>,;
                                    <{bFilter}>,;
                                    <{bAtSetFocus}>, <{bAtKillFocus}>,;
                                    <{bClose}>,;
                                    <{bSpecProc}>,;
                                    <aDelete>,;
                                    <lCanEdit>,;
                                    <"cExitBottom">,;
                                    <"cExitFormBottom">,;
                                    <aBox>)

#xtranslate cabEntry  CREATE FORM   <oForm> ;      // Variável que conterá o objeto
                     [DATASOURCE    <xSource>] ;    // Fonte de dados
                     [DESCRIPTION   <aDescri>] ;    // Array contendo a descrição. Vide:
                                                      ;// cabEntry CREATE DESCRIPTION
                                                      ;// cabEntry ADD COLUMN
                     [AT            <nTop>,<nLeft>, <nBot>,<nRight>] ;  // Screen Coord.
                     [BOX           <aBox>] ;                           // Tipo do Box
                     [FORMDESCRIPT  <aFormDesc>] ; // Array contendo a descrição para o
                                                       ;// Editor tipo "formulário".
                     [HASVBARR      <lVBarr>] ;    // Exibir barra de rolagem vertical?
                     [FORMIDENT     <bIdent>] ;    // Bloco de identificar o "formulário"
                     [EXITTOP       <lExitTop>] ;  // Retornar ao programa em :hitTop?
                     [ATCLOSE       <bClose>] ;    // Bloco para se executar quando se
                                                      ;// vai encerrar a edição
                     [SPECIALPROC   <bSpecProc>] ; // Procedimentos especiais quando se
                                                      ; // vai iniciar e encerrar o
                                                      ; // Event loop
                     [DELETESPEC    <aDelete>] ;   // Descrição dos procedimentos para
                                                      ; // deleção de linhas
                     [CANEDIT       <lCanEdit>] ;  // Browse pode ser editado?
                     [EXITFORMBOTTOM <cExitFormBottom:YES,NO,ALERT,&>] ; // Pode-se sair
                                                                            ;// em :hitBottom?
                     [SAMEDESCRIPT  <lTogheter>] ; // Vetor <adescri> será compartilhado com
                                                      ;// "browse pai"?
            => <oForm> := EditForm_(<nTop>,<nLeft>,;
                                    <nBot>,<nRight>,;
                                    <xSource>,;
                                    <aDescri>,;
                                    <aFormDesc>,;
                                    <lVBarr>,;
                                    <{bIdent}>,;
                                    <lExitTop>,;
                                    <{bClose}>,;
                                    <{bSpecProc}>,;
                                    <aDelete>,;
                                    <lCanEdit>,;
                                    <lTogheter>,;
                                    <"cExitFormBottom">,;
                                    <aBox>)
PROCEDURE Main(xParam)
cabEntry CREATE BROWSE    oGetArray;
         AT               12,11, 19,66;
         DATASOURCE       aMacete;
         DESCRIPTION      aDesc;
         BROWCOLOR        cnorm_;
         FORMDESCRIPT     aForm;
         ATSETFOCUS       {|nInd| e_dizqual(nInd, m_qtpla)};
         FREEZE           1;
         SHOWHEADER       .t.;
         HASVBARR         .t.;
         HASHBARR         .f.;
         ROWBYROW         .t.;
         EXITTOP          .t.;
         EXITFORMBOTTOM   YES;
         CANAPPEND        .f.
         
cabEntry CREATE BROWSE    oGetArray;
         AT               12,11, 19,66;
         DATASOURCE       aMacete;
         DESCRIPTION      aDesc;
         BROWCOLOR        cnorm_;
         FORMDESCRIPT     aForm;
         ATSETFOCUS       {|nInd| e_dizqual(nInd, m_qtpla)};
         FREEZE           1;
         SHOWHEADER       .t.;
         HASVBARR         .t.;
         HASHBARR         .f.;
         ROWBYROW         .t.;
         EXITTOP          .t.;
         EXITFORMBOTTOM   YES;
         CANAPPEND        .f.

   if oBrow:Cargo[L_CANEDIT]
      cabEntry  CREATE FORM    oBrow:Cargo[O_FORM];
                AT             aCoord[01],aCoord[02], aCoord[03],aCoord[04];
                DATASOURCE     oBrow:cargo[X_SOURCE];
                DESCRIPTION    oBrow:Cargo[A_DESCCOLS];
                FORMDESCRIPT   aFormDesc;
                HASVBARR       lVBarr;
                EXITTOP        .f.;
                CANEDIT        oBrow:Cargo[L_CANEDIT];
                EXITFORMBOTTOM ALERT;
                SAMEDESCRIPT   .t.
   else
      cabEntry  CREATE FORM    oBrow:Cargo[O_FORM];
                AT             aCoord[01],aCoord[02], aCoord[03],aCoord[04];
                DATASOURCE     oBrow:cargo[X_SOURCE];
                DESCRIPTION    oBrow:Cargo[A_DESCCOLS];
                FORMDESCRIPT   aFormDesc;
                HASVBARR       lVBarr;
                EXITTOP        .f.;
                CANEDIT        oBrow:Cargo[L_CANEDIT];
                EXITFORMBOTTOM NO;
                SAMEDESCRIPT   .t.
   endif
RETURN